Delphi. Маленькие хитрости: Прозрачная форма (CreateRectRgn, CombineRgn, SetWindowRgn).

unit UnitClass;

interface

uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls;

type

  TfrmGlass = class(TForm)

    Button1: TButton;

    Button2: TButton;

  private

    { Private declarations }

  protected

    procedure RebuildWindowRgn;

    procedure Resize; override;

  public

    { Public declarations }

    constructor Create(AOwner: TComponent); override;

  end;

var

  frmGlass: TfrmGlass;

implementation

{$R *.dfm}

{ Прозрачная форма }

constructor TfrmGlass.Create(AOwner: TComponent);

begin

  inherited;

  // убираем сколлбары, чтобы не мешались

  // при изменении размеров формы

  HorzScrollBar.Visible:= False;

  VertScrollBar.Visible:= False;

  // строим новый регион

  RebuildWindowRgn;

end;

procedure TfrmGlass.Resize;

begin

  inherited;

  // строим новый регион

  RebuildWindowRgn;

end;

procedure TfrmGlass.RebuildWindowRgn;

var

  FullRgn, Rgn: THandle;

  ClientX, ClientY, I: Integer;

begin

  // определяем относительные координаты клиенской части

  ClientX:= (Width - ClientWidth) div 2;

  ClientY:= Height - ClientHeight - ClientX;

  // создаем регион для всей формы

  FullRgn:= CreateRectRgn(0, 0, Width, Height);

  // создаем регион для клиентской части формы

  // и вычитаем его из FullRgn

  Rgn:= CreateRectRgn(ClientX, ClientY, ClientX + ClientWidth, ClientY + ClientHeight);

  CombineRgn(FullRgn, FullRgn, Rgn, rgn_Diff);

  // теперь добавляем к FullRgn регионы каждого контрольного элемента

  for I:= 0 to ControlCount -1 do

    with Controls[I] do begin

      Rgn:= CreateRectRgn(ClientX + Left, ClientY + Top, ClientX + Left + Width, ClientY + Top + Height);

      CombineRgn(FullRgn, FullRgn, Rgn, rgn_Or);

    end;

  // устанавливаем новый регион окна

  SetWindowRgn(Handle, FullRgn, True);

end;

end.